{ Uýdavinio autorius: doc. Gintautas Grigas, Matematikos ir informatikos
  institutas;
  SprendimÝ bei testus rengó: Rimas Misevißius, Lietuvos policijos akdemijos
  programuotojas ir Irus Grinis, Vilniaus "Üýuolyno" v.m. informatikos
  mokytojas }
  
program centai;

  function min(a, b: integer): integer;
  begin
    if (a < b)
      then min := a
      else min := b;
  end;

var
  kiek: array[0..4] of integer;
  n, i, k, ind, kaina: integer;
  n12, n34: integer;
  maxi, psk: integer;
  f: text;
begin
  { uýpildome nuliais }
  for ind := 0 to 4 do
    kiek[ind] := 0;

  { klasifikuojame kainas }
  assign(f, 'centai.dat');
  reset(f);
  readln(f, n);
  for i := 1 to n do
  begin
    readln(f, kaina);
    ind := kaina mod 5;
    kiek[ind] := kiek[ind] + 1;
  end;
  close(f);

  { 3+4 --> 2 }
  k := min(kiek[3], kiek[4]);
  kiek[2] := kiek[2] + k;
  kiek[3] := kiek[3] - k;
  kiek[4] := kiek[4] - k;

  { 3+3+3+3 --> 2 }
  kiek[2] := kiek[2] + kiek[3] div 4;
  kiek[3] := kiek[3] mod 4;
  { 3+3 --> 1 }
  kiek[1] := kiek[1] + kiek[3] div 2;
  kiek[3] := kiek[3] mod 2;

  { 4+4+4 --> 2 }
  kiek[2] := kiek[2] + kiek[4] div 3;
  kiek[4] := kiek[4] mod 3;

  { 1+1 --> 2 }
  kiek[2] := kiek[2] + kiek[1] div 2;
  kiek[1] := kiek[1] mod 2;

  { Max i÷lo÷is }
  maxi := kiek[1] + 2 * kiek[2] - 2 * kiek[3] - kiek[4];

  { minimalus pirkimù skaißius }
  n34 := 0;
  if (kiek[3] > 0) or (kiek[4] > 0) then
  begin
    k := -2 * kiek[3] - kiek[4];
    { dedam prie 1 ct }
    if kiek[1] > 0 then
    begin
      k := k + 1;
      kiek[1] := kiek[1] - 1;
    end;
    { dedam prie 2 ct }
    if kiek[2] > 0 then
    begin
      k := k + 2;
      kiek[2] := kiek[2] - 1;
    end;
    { grupuojam }
    if k = 0 then
      kiek[0] := kiek[0] + 1
    else if k = 1 then
      kiek[1] := kiek[1] + 1
    else if k = 2 then
      kiek[2] := kiek[2] + 1
    else
      n34 := 1;
  end;
  if n34 > 0 then
    psk := 1
  else begin
    n12 := kiek[1] + kiek[2];
    if n12 > 0 then
      psk := n12
    else if kiek[0] > 0 then
      psk := 1
    else
      psk := 0;
  end;

  { rezultatas }
  assign(f, 'centai.rez');
  rewrite(f);
  writeln(f, maxi, ' ', psk);
  close(f);
end.
