program skaiciaus_saknis;
  { Skaičiaus šaknis; (14 olimp, I etapas, vyr. grupė }
  function saknis (n: longint): longint;
    { šaknis, apskaičiuojama sąlygoje nurodytu būdu }
    var dal, skaitmuo, sak: longint;
  begin
    dal := 1;
    while n div dal >= 10 do
      dal := dal * 10;
    sak := 0;
    while n > 9 do
      begin
        skaitmuo := n div dal; { randame pirmą skaitmenį }
        sak := sak + skaitmuo;
        if sak >= 10 then sak := sak - 9;
        { atnaujiname n ir dal reikšmes }
        n := n mod dal;
        dal := dal div 10;
      end;
    sak := (sak + n) div 10 + (sak + n) mod 10;
    saknis := sak
  end; { šaknis }

  function saknis_T (n: longint): longint;
  { šaknis, apskaičiuojama tradiciniu būdu (irgi aprašytu sąlygoje) }
    var sak: integer;
  begin
    sak := 0;
    while sak = 0 do { kol skaitmenų suma didesnė už 10 }
      begin
        while n > 0 do  { sudedame skaičiaus skaitmenis }
          begin
            sak := sak + n mod 10;
            n := n div 10;
          end;
        if sak >= 10 then
            begin
              n := sak; sak := 0;
            end;
      end;
    saknis_T := sak;
  end;  { šaknis_T }

  function saknis_G (n: longint): longint;
    { šaknis skaičiuojama sudedant skaitmenis nuo skaičiaus galo }

    var sak: longint;
  begin
    sak := 0;
    while n > 0 do
      begin
        sak := sak + n mod 10;
        if sak >= 10 then sak := sak - 9;
        n := n div 10
      end;
    saknis_G := sak;
  end; { šaknis_G }

  var n, sak: longint;
begin
  readln (n);
  sak := saknis(n);
{ sak := saknis_T(n); }
{ sak := saknis_G(n); }
  writeln (sak);
end.