program lotyniskas_kvadratas;
  const PR = 'LOTYN6.DAT';
        RZ = 'LOT6.REZ';
        MAX_N = 26; { maksimalus kvadrato dydis }
  type kvadratas = array [1..MAX_N, 1..MAX_N] of char;

  procedure lot_kv (n: integer; kv: kvadratas;
                    var lot: boolean; { ar lotyni6kas }
                    var eil, stu: integer);
    var raides, aibe_eil, aibe_stu: set of char;
        i, j, kiek: integer;
        c: char;
  begin
    raides := [];  { panaudotos raidės }
    eil := 0; stu := 0;
    for i := 1 to n do
      begin
        aibe_eil := []; aibe_stu := [];
        { iš karto tikrinsime i-ąją eilutę ir i-ąjį stulpelį }
        for j := 1 to n do
          begin
            if kv[i, j] in aibe_eil { jei raidė kartojasi }
               then  eil := i
               else aibe_eil :=aibe_eil + [kv[i, j]];
            if kv[j, i] in aibe_stu { jei raidė kartojasi }
               then stu := i
               else aibe_stu :=aibe_stu + [kv[j, i]];
             raides := raides + [kv[i, j]];
          end;
      end;
    { suskaičiuosime kiek skirtingų raidžių panaudota }
    kiek := 0;
    for c := 'A' to 'Z' do
      if c in raides then kiek := kiek + 1;
    lot := (eil = 0) and (stu = 0) and (kiek = n);
  end; { lot_kv }

  procedure skaityti (var n: integer; var kv: kvadratas);
    var f: text;
        i, j: integer;
  begin
    assign (f, PR);
    reset (f);
    readln (f, n);
    for i := 1 to n do
      begin
        for j := 1 to n do
           read (f, kv[i, j]);
        readln (f);
      end;
    close(f);
  end; { skaityti }

  procedure isvesti (lot: boolean; var eil, stu: integer);
    var f: text;
  begin
    assign (f, RZ);
    rewrite (f);
    if lot then writeln (f, 'TAIP')
           else writeln (f, 'NE');
    writeln (f, eil);
    writeln (f, stu);
    close (f);
  end; { išvesti }

  var n, eil, stu: integer;
      kv: kvadratas;
      lot: boolean;
begin
  skaityti (n, kv);
  lot_kv (n, kv, lot, eil, stu);
  isvesti (lot, eil, stu)
end.