program simboliu_keitimas;

  const MaxK = 700;
        DF ='SIMB.DAT';
        RF ='SIMB.REZ';


  type Virsune = record
         aIs : set of char;  { Ið kokiø raidþiø reikës keisti á ðià. }
         aI : char;          { Á koká simbolá reikës keisti ðià raidæ. }
       end;
       TGrafas = array ['A' .. 'Z'] of Virsune;

{ Tokiame masyve saugosiu surastà atsakymà. }
       TKaipKeisti = array [1 .. MaxK] of string[2];

  procedure Negalima;
    var f: text;
  begin
    assign (f, RF);
    rewrite (f);
    writeln(f, 0);
    close (f);
    halt;
  end;


{ Nuskaitau pradinius duomenis. }
  procedure Ivedimas(var Mas : TGrafas; var N : integer);
    var i : integer;
        cIs, cI : char;
        f: text;
  begin
{ Susidarau tuðèià grafà. }
    for  cI := 'A' to 'Z' do
    begin
      Mas[cI].aIs := [];
      Mas[cI].aI := ' ';
    end;

    assign (f, DF);
    reset (f);
    readln(f, N);
    for i := 1 to N do
    begin
      read(f, cIs, cI);

{ Tikrinu, ar nëra kito keitimo, keisianèio ðá simbolá. }
      if Mas[cIs].aI <> ' ' then Negalima;

      Mas[cIs].aI := cI;
      Mas[cI].aIs := Mas[cI].aIs + [cIs];

{ Jeigu tai nebuvo paskutinë pora, reikia nuskaityti tarpà, esantá tarp
keitimø. }
      if i <> N then
        read(f, cIs);
    end;
    close (f);
  end;


{ Randu simbolá, kurio jau nebereikës keisti á joká kità. }
  function VirsuneBeIsejimu(Mas : TGrafas) : char;
    var cI : char;
  begin
    for cI := 'A' to 'Z' do
      if (Mas[cI].aIs <> []) and (Mas[cI].aI = ' ') then
      begin
        VirsuneBeIsejimu := cI;
        exit;
      end;
    VirsuneBeIsejimu := ' ';
  end;


{ Ieðko sprendinio.
  Jeigu sprendinys rastas, gràþina reikðmæ TRUE ir, per parametrà kintamàjá Ats,
patá sprendiná.
  Jeigu sprendinys nerastas, gràþina reikðmæ FALSE. }
  function Sprendimas(Mas : TGrafas; N : integer; var Ats : TKaipKeisti)
    : boolean;
    var II : integer;
        Virs, cI : char;
  begin
    Sprendimas := true;
    II := 0;

{ Suksiu ciklà, kol visus keitimus surikiuosiu teisingai }
    while n <> II do
    begin

{ Randu simbolá, kurio jau nebereikës keisti á joká kità. }
      Virs := VirsuneBeIsejimu(Mas);
      if Virs <> ' ' then
      begin

{ Pasiþymiu, jog galiu atlikti visus keitimus susijusius su
rastuoju simboliu. }
        for cI := 'A' to 'Z' do
          if cI in Mas[Virs].aIs then
          begin
            Inc(II);
            Ats[II] := cI + Virs;
            Mas[cI].aI := ' ';
          end;
        Mas[Virs].aIs := [];

      end else begin

        if II <> N then
          Sprendimas := false;
        exit;

      end;

    end;
  end;

{ Iðspausdinu rastà atsakymà. }
  procedure Atsakymas(Mas : TKaipKeisti; N : integer);
    var i : integer;
        f: text;
  begin
    assign (f, RF);
    rewrite (f);
    for i := 1 to N do
      write(f, Mas[i], ' ');
    close (f);
  end;

  var N : integer;
      Mas : TGrafas;
      Ats : TKaipKeisti;

begin
{ Ávedu pradinius duomenis. }
  Ivedimas(Mas, N);

{ Ieðkau sprendinio. }
  if Sprendimas(Mas, N, Ats) then
    Atsakymas(Ats, N)
  else
    Negalima;
end.
