{
TASK:PRANESIMAS
LANG:PASCAL
}
program slaptas_pranesimas;

  const PRAD='PRAN3.DAT';
        REZ='PRAN.REZ';
        MAX=100; { maksimalus eilučių skaičius }
        RIL=5; { raidės kodo ilgis }

  type Tmas = array [1..MAX] of string[50];

  procedure rasti_vienodas (n: integer; eil: Tmas; var eilute: string);
    { randa dvi vienodas eilutes rikiuojant išrinkimu }
    var i, j: integer;
        a: string;
  begin
    for i := 2 to n do
      begin
        a := eil[i]; j := i;
        while (j > 1) and (a < eil[j-1]) do
          begin
            eil[j] := eil[j-1];
            j := j - 1;
          end;
        if (j > 1) and (a = eil[j-1]) { radome vienodas eilutes }
           then begin
                  eilute := a;
                  exit; { išeinama iš procedūros }
                end;
        eil[j] := a;
      end; { for }
  end; { rasti_vienodas }

  function raide (kodas: string): char;
    { pagal raides kodą randa raidę }
    var i, laip, des: integer;
  begin
   { kodas perrašomas dešimtainiu skaičiumi }
    laip := 1; des := 0;
    for i := RIL downto 1 do
      begin
        if kodas[i]='1'
            then des := des + laip;
        laip := laip*2;
      end;
    { dešimtainis skaičius paverčiamas raide }
    raide := chr(des + ord('A'));
  end; { raide }

  procedure desifruoti (eilute: string; var tekstas: string);
    { dešifruoja vieną eilutę }
    var i: integer;
        kodas: string;
  begin
    tekstas := '';
    while length(eilute) >= RIL do { dešifruojama kiekviena raidė }
      begin
        kodas := copy (eilute, 1, RIL);
        delete (eilute, 1, RIL);
        tekstas := tekstas + raide (kodas);
      end;
  end; { dešifruoti }

  procedure skaityti (var n: integer; var eil: Tmas);
    var f: text;
        i: integer;
  begin
   assign (f, PRAD);
   reset (f);
   readln (f, n);
   for i := 1 to n do
     readln (f, eil[i]);
   close (f);
  end; { skaityti }

  procedure spausdinti (tekstas: string);
    var f: text;
  begin
    assign (f, REZ);
    rewrite (f);
    writeln (f, tekstas);
    close (f);
  end; { spausdinti }

  var n: integer;
      eil: Tmas;
      tekstas, eilute: string;
begin
  skaityti (n, eil);
  rasti_vienodas (n, eil, eilute);
  desifruoti (eilute, tekstas);
  spausdinti (tekstas);
end.